Grammar

Document ::= Entry*

Entry    ::= DocComment? Atom+

DocComment
         ::= ( '///' NonNewline* Newline )+

Atom     ::= Scalar
           | Sequence
           | Object
           | '@'
           | Tag
           | Attributes

Scalar   ::= BareScalar
           | QuotedScalar
           | RawScalar
           | HeredocScalar

BareScalar
         ::= BareChar+

BareChar ::= [^{}(),"=@#x20#x09#x0A#x0D]

QuotedScalar
         ::= '"' QuotedChar* '"'

QuotedChar
         ::= EscapeSeq
           | [^"\]

EscapeSeq
         ::= '\' ( [\"nrt0] | 'u' HexDigit HexDigit HexDigit HexDigit | 'u{' HexDigit HexDigit? HexDigit? HexDigit? HexDigit? HexDigit? '}' )

HexDigit ::= [0-9A-Fa-f]

RawScalar
         ::= 'r' '#'* '"' RawChar* '"' '#'*

RawChar  ::= [^"]+

HeredocScalar
         ::= '<<' Delimiter Newline HeredocLine* Delimiter

Delimiter
         ::= [A-Z] [A-Z0-9_]*

HeredocLine
         ::= NonNewline* Newline

Tag      ::= '@' TagName TagPayload?

TagName  ::= [A-Za-z_] [A-Za-z0-9_.#x2D]*

TagPayload
         ::= Object
           | Sequence
           | QuotedScalar
           | RawScalar
           | HeredocScalar
           | '@'

Sequence ::= '(' WS* ( Atom ( WS+ Atom )* )? WS* ')'

Object   ::= '{' ObjectBody '}'

ObjectBody
         ::= NewlineSeparated
           | CommaSeparated
           | WS*

NewlineSeparated
         ::= WS* Entry ( Newline+ Entry )* WS*

CommaSeparated
         ::= WS* Entry ( ',' Entry )* WS*

Attributes
         ::= Attribute+

Attribute
         ::= BareScalar '=' AttributeValue

AttributeValue
         ::= BareScalar
           | QuotedScalar
           | Sequence
           | Object

LineComment
         ::= '//' NonNewline*

WS       ::= [#x20#x09#x0A#x0D]
           | LineComment

Newline  ::= #x0D? #x0A

NonNewline
         ::= [^#x0A#x0D]